init

PKGBUILD

@@ -0,0 +1,56 @@
+# Originally base on PKGBUILD from archlinux AUR
+# https://aur.archlinux.org/cgit/aur.git/tree/PKGBUILD?h=awesome-git
+
+_pkgname=awesome
+pkgname=${_pkgname}-git
+pkgver=4.3.959.g32827126
+pkgrel=1
+pkgdesc='Highly configurable framework window manager'
+arch=('i686' 'x86_64')
+url='http://awesome.naquadah.org/'
+license=('GPL2')
+depends=('cairo' 'dbus' 'gdk-pixbuf2' 'libxdg-basedir' 'libxkbcommon-x11'
+         'lua53' 'lua53-lgi' 'pango' 'startup-notification' 'xcb-util-cursor'
+         'xcb-util-keysyms' 'xcb-util-wm' 'xcb-util-xrm' 'libxfixes')
+makedepends=('asciidoc' 'cmake' 'docbook-xsl' 'git' 'imagemagick' 'ldoc'
+             'xmlto')
+optdepends=('rlwrap: readline support for awesome-client'
+            'dex: autostart your desktop files'
+            'xcb-util-errors: for pretty-printing of X11 errors'
+            'librsvg: for displaying SVG files without scaling artifacts')
+provides=('notification-daemon' 'awesome')
+conflicts=('awesome')
+backup=('etc/xdg/awesome/rc.lua')
+source=("$pkgname::git+https://github.com/Aire-One/awesome.git")
+md5sums=('SKIP')
+_LUA_VER=5.3
+
+pkgver() {
+  cd $pkgname
+  git describe | sed 's/^v//;s/-/./g'
+}
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../$pkgname \
+    -DCMAKE_BUILD_TYPE=RELEASE \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DSYSCONFDIR=/etc \
+    -DLUA_INCLUDE_DIR=/usr/include/lua${_LUA_VER} \
+    -DLUA_LIBRARY=/usr/lib/liblua.so.${_LUA_VER} \
+    -DLUA_EXECUTABLE=/usr/bin/lua${_LUA_VER}
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+
+  install -Dm644 "$srcdir"/$pkgname/awesome.desktop \
+    "$pkgdir/usr/share/xsessions/awesome.desktop"
+}
+